VBA-Beispiel 059
mail schreiben
mail schreiben

markierte Zellen von Excel nach Word kopieren

Exportiert den markierten Zellbereich von Excel in das aktive Worddokument.
Sub markierten_Zellbereich_nach_Word_kopieren()
'kopiert den markierten Zellbereich in das aktive Word-Document
'unter Extras - Verweise muß der Eintrag
'Microsoft Word Object Library    aktiviert sein

Dim Word_App As Word.Application
Dim Word_Doc As Word.Document

Const Word_läuft_nicht As Long = 429
Const Word_kein_Dokument As Long = 4248

On Error Resume Next

Set Word_App = GetObject(, "Word.Application")

'prüfen ob Word läuft
If Err.Number = Word_läuft_nicht Then
    MsgBox "Word ist leider nicht gestartet.", , "Abbruch"
    Set Word_App = Nothing
    Exit Sub
End If

Set Word_Doc = Word_App.ActiveDocument

'prüfen ob Word ein aktives Dokument hat
If Err.Number = Word_kein_Dokument Then
    MsgBox "Word hat kein aktives Dokument", , "Abbruch"
    Set Word_Doc = Nothing
    Set Word_App = Nothing
    Exit Sub
End If  

On Error GoTo Fehler

   'markierte Zellen kopieren
    Selection.Copy

   'in Word einfügen
    Word_App.Selection.PasteSpecial Link:=False, DataType:=wdPasteRTF, _
        Placement:=wdInLine, DisplayAsIcon:=False

   'Speicher freigeben
    Set Word_Doc = Nothing
    Set Word_App = Nothing
    Application.CutCopyMode = False
Exit Sub

Fehler:
    Set Word_Doc = Nothing
    Set Word_App = Nothing
    Application.CutCopyMode = False

    MsgBox "FehlerNr.: " & Err.Number & vbNewLine & vbNewLine _
    & "Beschreibung: " & Err.Description _
    , vbCritical, "Fehler"
End Sub

Download:   vba059.zip