VBA-Beispiel 071
mail schreiben
mail schreiben

mit VBA Diagramm als GIF speichern
In diesem Beispiel wird das Diagramm einer Exceldatei als Bilddatei (GIF) gespeichert.
Als Dateiname für die Bilddatei wird - falls vorhanden - der Diagrammtitel verwendet.
Sub Diagramm_als_GIF_speichern()
Dim Diagramm As Excel.Chart
Dim Dateiname As String

On Error GoTo Hell

Set Diagramm = ActiveSheet.ChartObjects(1).Chart

'wenn vorhanden, Diagrammtitel als Dateiname verwenden
If Diagramm.HasTitle = True Then
  Dateiname = "\" & Diagramm.ChartTitle.Text & ".gif"
Else
  Dateiname = "\ohne Titel.gif"
End If

'Diagramm als GIF speichern
Diagramm.Export Filename:=ThisWorkbook.Path & Dateiname, FilterName:="gif"

Set Diagramm = Nothing

'Info zu Speicherpfad + Frage wg Anzeige
If MsgBox("Diagramm gespeichert in:" _
        & vbNewLine & vbNewLine _
        & ThisWorkbook.Path & Dateiname _
        & vbNewLine & vbNewLine _
        & "Datei anzeigen?", vbYesNo, "") = vbYes Then
        Shell "hh " & ThisWorkbook.Path & Dateiname, vbMaximizedFocus
End If

Exit Sub

Hell:
    Set Diagramm = Nothing

    MsgBox "FehlerNr.: " & Err.Number & vbNewLine & vbNewLine _
    & "Beschreibung: " & Err.Description _
    , vbCritical, "Fehler"
End Sub
Download:   vba071.zip
relevante Links:

top