VBA-Beispiel 101
mail schreiben
mail schreiben

markierte Zellen als GIF speichern

Erstellt von den markierten Zellen eine Bilddatei (GIF) im Ordner dieser Exceldatei. Wurden mit Strg + Maus mehrere Zellbereiche markiert, wird für jeden Zellbereich ein GIF erstellt.
Sub Zellen_als_Bild_erportieren()
'erstellt von den markierten Zellen eine Bilddatei (GIF)
Dim Zellbereich As Range
Dim Anz_Markierungen As Integer
Dim Bild As Picture
Dim Diagramm As ChartObject

On Error GoTo Hell      'falls "Abbrechen" gedrückt wird
'Zellen markieren (Bildbereich)
Set Zellbereich = Application.InputBox _
  (prompt:="Markieren Sie die Zellen für das Bild" & vbNewLine & _
           "mit Strg + Maus Mehrfachmarkierungen möglich", _
   Title:="Bildauswahl", Type:=8)
On Error GoTo 0

Application.ScreenUpdating = False

'Schleife falls mehrere Bereiche markiert wurden
'für jeden Bereich ein GIF erstellen
For Anz_Markierungen = 1 To Zellbereich.Areas.Count

  Zellbereich.Areas(Anz_Markierungen).Copy
  Worksheets.Add
  Set Bild = ActiveSheet.Pictures.Paste(Link:=True)
  Bild.CopyPicture Appearance:=xlScreen, Format:=xlPicture

  Set Diagramm = ActiveSheet.ChartObjects.Add(0, 0, Bild.Width, Bild.Height)

  With Diagramm
    .Chart.Paste
    .Chart.Export Filename:=ActiveWorkbook.Path & "\test" & Anz_Markierungen & ".gif", FilterName:="gif"
  End With

  Application.DisplayAlerts = False
  ActiveSheet.Delete
  Application.DisplayAlerts = True
  Application.ScreenUpdating = True
Next Anz_Markierungen

Application.ScreenUpdating = True

Set Diagramm = Nothing
Set Bild = Nothing
Set Zellbereich = Nothing
Exit Sub

Hell:
  MsgBox "", , "Abbruch"
End Sub

Download:   vba101.zip